# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=portsmf
pkgver=0.1
_debver=0.1
_debpkg=~svn20101010
_debrel=5
pkgrel=1
pkgdesc='Portable library for reading/writing Standard MIDI Files'
arch=('i686' 'x86_64')
url='https://sourceforge.net/p/portmedia/wiki/portsmf/'
license=('Expat')
depends=('gcc-libs' 'glibc')
makedepends=('quilt')
options=('!staticlibs')
source=("https://deb.debian.org/debian/pool/main/p/portsmf/${pkgname}_${pkgver}${_debpkg}.orig.tar.bz2"
        "https://deb.debian.org/debian/pool/main/p/portsmf/portsmf_${_debver}${_debpkg}-${_debrel}.debian.tar.xz")
sha512sums=('51d27c238241de19cfb4f3230dacaee8335b77b7b7a48f8a68f85edddcf2da94bd64e3a122487ae50ed9113e14f9db1df43482758a4814c8ddd1c79d38f1666d'
            'c65b8b0d8ac0666b2c1784ce8d4e05f0d129d0cef2b7171a6cf4263c419ccf81f99b0b7c8998c1217549e3eff37bd81fea0b498945ca3e7c1a4934f99c75a2ff')

prepare() {
  mv ${pkgname}-${pkgver}${_debpkg} ${pkgname}-${pkgver}
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  autoreconf -vfi
  chmod 755 configure
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr \
              --libdir=/usr/lib \
              --includedir=/usr/include/portsmf
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" includedir=/usr/include/portsmf install
  install -vDm 644 portSMF.pc -t "${pkgdir}/usr/lib/pkgconfig/"
  install -vDm 644 license.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  install -vDm 644 README.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
}