# Maintainer: Jesus E. <heckyel@riseup.net>

_pkgname=pmount
pkgname=$_pkgname-safe-removal
pkgver=0.9.23
_debver=$pkgver
_debrel=6
pkgrel=2
pkgdesc="Mount removable devices as normal user, with safe removal of device"
arch=('i686' 'x86_64')
license=('GPL-2')
url='https://salsa.debian.org/debian/pmount'
backup=('etc/pmount.allow')
depends=('sysfsutils' 'bash' 'util-linux')
makedepends=('intltool' 'gettext-tiny')
provides=('pmount')
conflicts=('pmount')
source=(${pkgname}-${pkgver}.tar.bz2::https://deb.debian.org/debian/pool/main/p/pmount/pmount_${pkgver}.orig.tar.bz2
        fix-package.patch)
sha512sums=('a9d762fb9bd3f525d52b29a33c09c10a09f90fabdeed8f3658cb3fe8cbdbf237b2c9165b7c93a7170b9de5c65c513c1629b1fca638563a66d091c518782db92d'
            '9dd33f1bd0eaaefc087801ecd31b7f8b89a92b1e9ea806c145c9911caa09b753caaf85e2ff0887dd0ba6829518f90ec785b2dce7dfb68b9db30538b51e284142')

prepare() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  patch -p1 -i ${srcdir}/fix-package.patch
}

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  ./configure --prefix=/usr --disable-hal \
    --with-cryptsetup-prog=/usr/bin/cryptsetup
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -dm755 "$pkgdir"/media
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}