# Maintainer: Jesus E. <heckyel@riseup.net>
# Packager (Arch): Maksim Sipos (maxsipos at gmail dot com)

pkgname=plotutils
pkgver=2.6
_debver=2.6
_debrel=11
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc='Set of utilities and libraries for plotting.'
url='https://directory.fsf.org/graphics/plotutils.html'
license=('GPL-3')
depends=('libpng' 'gcc-libs' 'libxaw')
makedepends=('quilt')
source=(https://ftp.gnu.org/pub/gnu/plotutils/$pkgname-$pkgver.tar.gz{,.sig}
        https://deb.debian.org/debian/pool/main/p/plotutils/plotutils_$_debver-$_debrel.debian.tar.xz)
sha512sums=('4e5982605e5c1fbdb7325069c3ab2edd736e37a2eb30a1ec01fdc3541fcee6ed49937d4814c6baf79dab5b6fa42f909e4800c851d0ace3c7cf6d5a8681d0f0e7'
            'SKIP'
            'f9a3c495a9c7e443cb088b8a4383c4c7570a2652f73abbe833a62fdf4373a608498b1a4c2f20e3e027f48ec80114456e17261e967ccb33d6e0131e6ffe82910d')
validpgpkeys=('C7823604DFEA27BC29DD4F179DEB46C0D679F6CF') # Karl Berry

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr \
	--with-gnu-ld \
	--with-x \
	--enable-libplotter
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}