# Maintainer: Jesus E. <heckyel@riseup.net>

# This must be built against the version of dovecot being used,
# else mail delivery will fail.
# Specify the version of dovecot to be used here:
_dcpkgver=2.3.13
_dcmajor=2.3
# Make sure to bump pkgrel if changing this.

pkgname=pigeonhole
pkgver=0.5.13
pkgrel=1
pkgdesc='Sieve implementation for Dovecot'
url='https://pigeonhole.dovecot.org/'
arch=('i686' 'x86_64')
license=('LGPL-2.1')
depends=("dovecot=${_dcpkgver}")
conflicts=('dovecot-sieve' 'pigeonhole-hg')
source=("https://pigeonhole.dovecot.org/releases/2.3/dovecot-${_dcmajor}-pigeonhole-${pkgver}.tar.gz"{,.sig})
sha512sums=('fcbc13d71af4e6dd4e34192484e203d755e5015da76a4774b11a79182b2baad36cab5a471346093111ace36a7775dfe8294555f8b777786dde386820b3ec5cd3'
            'SKIP')
validpgpkeys=(
              '42F3CD50D4F25A41833BEE3704D62B1E3DFBB4F4' # Stephan Bosch <stephan@rename-it.nl>
              '2BE74AAB3EE754DFB9C80D3318A348AEED409DA1'
             )

prepare() {
  cd "dovecot-${_dcmajor}-pigeonhole-${pkgver}"

  local filename
  for filename in "${source[@]}"; do
    if [[ "$filename" =~ \.patch$ ]]; then
      patch -p1 -N -l -i "$srcdir/${filename##*/}"
    fi
  done
}

build() {
  cd "dovecot-${_dcmajor}-pigeonhole-${pkgver}"

  ./configure \
    --prefix=/usr \
    --with-dovecot=/usr/lib/dovecot \
    --with-moduledir=/usr/lib/dovecot/modules \
    --disable-static
  make
}

package() {
  cd "dovecot-${_dcmajor}-pigeonhole-${pkgver}"

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING* -t "$pkgdir"/usr/share/licenses/$pkgname
}