# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=phonon-qt-gstreamer
pkgver=4.10.0
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc='Phonon GStreamer backend for Qt'
url='https://community.kde.org/Phonon'
license=('LGPL-2.1')
depends=('gst-plugins-base' 'qt-x11extras' 'phonon-qt' 'alsa-lib')
optdepends=('gst-plugins-good: additional codecs'
            'gst-plugins-bad: additional codecs'
            'gst-plugins-ugly: additional codecs'
            'gst-libav: libav codec')
makedepends=('extra-cmake-modules' 'qt-tools')
provides=('phonon-qt-backend')
source=("https://download.kde.org/stable/phonon/phonon-backend-gstreamer/$pkgver/phonon-backend-gstreamer-$pkgver.tar.xz"{,.sig})
sha512sums=('3beaba9ea3a332a6908ebdaa966958e8e8056d79cfb210e82a8edaf08f0a8bacbf8094e91b1b1b936406aa634dabb962e6c1468e4dde3febd9efac1a63ea70a4'
            'SKIP')
validpgpkeys=(CB9387521E1EE0127DA804843FDBB55084CC5D84) # Harald Sitter <sitter@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../phonon-backend-gstreamer-$pkgver
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
  install -Dm644 "${srcdir}/phonon-backend-gstreamer-${pkgver}/COPYING.LIB" -t "${pkgdir}/usr/share/licenses/$pkgname"
}