# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=phonon-gstreamer
pkgname=('phonon-qt4-gstreamer' 'phonon-qt5-gstreamer')
pkgver=4.9.0
pkgrel=2.hyperbola1
arch=('i686' 'x86_64')
url='https://phonon.kde.org/'
license=('LGPL-2.1')
optdepends=('gst-plugins-good: good codecs'
            'gst-plugins-bad: additional codecs'
	    'gst-plugins-ugly: additional codecs'
            'gst-libav: libav codec')
makedepends=('gst-plugins-base' 'extra-cmake-modules' 'automoc4' 'phonon-qt4' 'phonon-qt5' 'qt5-x11extras')
source=("https://download.kde.org/stable/phonon/phonon-backend-gstreamer/${pkgver}/phonon-backend-gstreamer-${pkgver}.tar.xz")
sha512sums=('9c13d37c6c7070c2bd8fcc562f743ac2f55289bc7cc82147ef0ae990e5d380d541cc1d9ce61e6ad1549ed1935d41faafaeeb0cd5463e4c656ea8fee636ff4dfe')

prepare() {
  mkdir build-qt4
  mkdir build-qt5
}

build() {
  cd build-qt4
  cmake ../${pkgbase}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    -D__KDE_HAVE_GCC_VISIBILITY=NO \
    -DCMAKE_INSTALL_LIBDIR=lib
  make

  cd ../build-qt5
  cmake ../${pkgbase}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -D__KDE_HAVE_GCC_VISIBILITY=NO \
    -DPHONON_BUILD_PHONON4QT5=ON
  make
}

package_phonon-qt4-gstreamer() {
  pkgdesc="Phonon GStreamer backend for Qt4, without pulseaudio recommendation"
  depends=(gst-plugins-base phonon-qt4)

  cd build-qt4
  make DESTDIR="${pkgdir}" install

# Conflict with -qt5
  rm -r "$pkgdir"/usr/share/icons
}

package_phonon-qt5-gstreamer() {
  pkgdesc="Phonon GStreamer backend for Qt5, without pulseaudio recommendation"
  depends=(gst-plugins-base qt5-x11extras phonon-qt5)

  cd build-qt5
  make DESTDIR="${pkgdir}" install
}