# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname='perl-role-tiny'
pkgver=2.002004
pkgrel=1
pkgdesc="Roles. Like a nouvelle cuisine portion size slice of Moose."
arch=('any')
license=('GPL-1')
url='https://search.cpan.org/dist/Role-Tiny/'
options=('!emptydirs')
depends=('perl')
source=("https://search.cpan.org/CPAN/authors/id/H/HA/HAARG/Role-Tiny-$pkgver.tar.gz")
sha512sums=('f66a799a0cd4e989adc173f6d913967df7aa6b9ffda934c2a80c0a91dcfe4edce606bd27cf1b4d857d52d0aa770224315ae4e915e4e735c6a9483a6cf5ce02f1')

build() {
  ( export PERL_MM_USE_DEFAULT=1 PERL5LIB=""                 \
      PERL_AUTOINSTALL=--skipdeps                            \
      PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='"$pkgdir"'"     \
      PERL_MB_OPT="--installdirs vendor --destdir '"$pkgdir"'" \
      MODULEBUILDRC=/dev/null

    cd "$srcdir/Role-Tiny-$pkgver"
    perl Makefile.PL
    make
  )
}

package() {
  cd "$srcdir/Role-Tiny-$pkgver"
  make install
  find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}