# Maintainer: Jesus E. <heckyel@riseup.net>
# Packager (Arch): Justin "juster" Davis <jrcd83@gmail.com>

pkgname=perl-path-class
pkgver=0.37
pkgrel=1
pkgdesc="Cross-platform path specification manipulation"
arch=('any')
license=('GPL-1')
options=(!emptydirs)
depends=('perl')
makedepends=('perl-module-build')
url="https://search.cpan.org/dist/Path-Class"
source=("https://search.cpan.org/CPAN/authors/id/K/KW/KWILLIAMS/Path-Class-${pkgver}.tar.gz")
sha512sums=('044d86f85eebff96bdff8fc11e97884eb4e06d56ecd2d3bfdc045135da6f08c40e644e0e5c1a779a8ef5d6c7c04e159e47721b4e637a92fed7d298b5f798ef83')

build()
(
  export PERL_MM_USE_DEFAULT=1 PERL5LIB="" \
         PERL_AUTOINSTALL=--skipdeps \
         PERL_MM_OPT="INSTALLDIRS=vendor" \
         PERL_MB_OPT="--installdirs vendor" \
         MODULEBUILDRC=/dev/null
  cd Path-Class-${pkgver}
  /usr/bin/perl Build.PL
  ./Build
)

package() {
  export PERL_MM_OPT="INSTALLDIRS=vendor DESTDIR='"$pkgdir"'" \
         PERL_MB_OPT="--installdirs vendor --destdir '"$pkgdir"'"

  cd Path-Class-${pkgver}
  ./Build install
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}