# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-io-tty
pkgver=1.15
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="Provide an interface to TTYs and PTYs"
arch=('i686' 'x86_64')
url='https://search.cpan.org/dist/IO-Tty/'
license=('GPL-1')
depends=('glibc')
makedepends=('quilt')
options=('!emptydirs')
source=("https://search.cpan.org/CPAN/authors/id/T/TO/TODDR/IO-Tty-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/libi/libio-pty-perl/libio-pty-perl_$_debver-$_debrel.debian.tar.xz")
sha512sums=('55329833d2e5ac426c0b69224e0af41d86c8dfd935c3698eb15800f0b7f48610651403ea54d9c7cad2f71b7c1080e957fa3706912680204f9b83c801095d2648'
            '3bb8061f5dfe6018d8c4da7710ae6d4b6977f365dc17a1bb65713658d2a32fa0a638ef15a5b17f01e7d75635d04a6238989d6545c02cff965b41003a8e546109')

prepare() {
  cd "$srcdir"/IO-Tty-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir"/IO-Tty-$pkgver
  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  cd "$srcdir"/IO-Tty-$pkgver
  make install DESTDIR="$pkgdir"
  find "$pkgdir" -name '.packlist' -delete
  find "$pkgdir" -name '*.pod' -delete
  install -Dm644 debian/copyright -t "${pkgdir}/usr/share/licenses/$pkgname"
}