# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-file-slurp
pkgver=9999.32
_debver=9999.32
_debrel=1
pkgrel=1
pkgdesc="Read/write/append files quickly"
arch=('any')
url="https://search.cpan.org/dist/File-Slurp"
license=('GPL-1')
depends=('perl')
makedepends=('quilt')
options=('!emptydirs')
source=(https://cpan.metacpan.org/authors/id/C/CA/CAPOEIRAB/File-Slurp-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/libf/libfile-slurp-perl/libfile-slurp-perl_$_debver-$_debrel.debian.tar.xz
        LICENSE)
sha512sums=('413337e0257e95e8e8d2aabf684bec81e746000a741809935b058490b8c42b494064f724e618b250330d8bb67a0a7a2a5adad17e3e6c96d4b193531a192a4d56'
            '5526b7c958e4cea0d36c2baf674ef89d2f4ba97810e617940db0c7f657638e806bbad6e338f26505781e02d31375718fd23ee82da87898e0a1c5df49cc79b325'
            'b3fe26789164a5133857733d2a5a28c2af3995accb50c147b6158f90efd7c9e35793b21d71b165445d734e281ba5d036d4799a65a4ebc468d49cbcd368d66aac')

prepare() {
  cd  "$srcdir"/File-Slurp-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd  "$srcdir"/File-Slurp-$pkgver
  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  cd  "$srcdir"/File-Slurp-$pkgver
  make install DESTDIR="$pkgdir"
  find "$pkgdir" -name '.packlist' -delete
  find "$pkgdir" -name '*.pod' -delete
  install -Dm644 "${srcdir}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}