# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-date-calc
_realname=Date-Calc
pkgver=6.4
_debver=$pkgver
_debrel=1.1
pkgrel=1
pkgdesc="Perl module for Gregorian calendar date calculations"
arch=('any')
license=('GPL-1')
url='https://search.cpan.org/dist/Date-Calc/'
depends=('perl-bit-vector' 'perl')
makedepends=('quilt')
options=(!emptydirs)
source=("https://search.cpan.org/CPAN/authors/id/S/ST/STBEY/Date-Calc-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libd/libdate-calc-perl/libdate-calc-perl_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('e2d0cb2b041afedb10033700e27075f01987abc763a59034a10a9fc0bb059706cc959f6d76fe1fc21ced4b547475f62a8c37ad38e8e49f7453d78b17082c0671'
            '441cc555052c1b0effe18868719140bfb0c7283bbfe2e7feb652644518bf9611d65861cf04c58727e22f58f381cd1f51c6725d80edf701c1bb8084c79edb98ce')

prepare() {
  cd Date-Calc-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd Date-Calc-$pkgver
  # install module in vendor directories.
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  cd Date-Calc-$pkgver
  make install DESTDIR="$pkgdir"
  install -Dm644 debian/copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}