# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-cairo-gobject
pkgver=1.005
_debver=1.005
_debrel=2
pkgrel=2
pkgdesc="Integrate Cairo into the Glib type system"
arch=('i686' 'x86_64')
url="https://metacpan.org/release/Cairo-GObject"
license=('LGPL-2.1')
makedepends=('perl-extutils-depends' 'perl-extutils-pkgconfig' 'quilt' 'gettext-tiny')
depends=('glib-perl' 'cairo-perl')
options=('!emptydirs')
source=("https://cpan.metacpan.org/authors/id/X/XA/XAOC/Cairo-GObject-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libc/libcairo-gobject-perl/libcairo-gobject-perl_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('45f1e3ff6f8a90347175c66e5a854acd22285cd48a9aa07344c046add283892d6188e88f69d64798dc5323cb17aa442853915ed2081b5ec4e2a735b89cd11b1e'
            'c3e4cc14c9e4b575dd348a38f33b65ab75ced0ec6c56491e37d3a8ee48129b6e9a18feeaf277d6a785e31c0808a3a51210da20c7ce64598d697eb58ff29d6058')

prepare() {
  cd "Cairo-GObject-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "Cairo-GObject-${pkgver}"
  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  perl Makefile.PL
  make
}

check() {
  cd "Cairo-GObject-${pkgver}"
  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  export PERL_MM_USE_DEFAULT=1
  make test
}

package() {
  cd "Cairo-GObject-${pkgver}"
  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  make pure_install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}

# vim:set ts=2 sw=2 et: