# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-bit-vector
pkgver=7.4
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc='Efficient bit vector, set of integers and "big int" math library'
arch=('i686' 'x86_64')
license=('GPL-1')
url='https://search.cpan.org/dist/Bit-Vector/'
depends=('perl-carp-clan')
makedepends=('quilt')
options=('!emptydirs')
source=("https://search.cpan.org/CPAN/authors/id/S/ST/STBEY/Bit-Vector-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libb/libbit-vector-perl/libbit-vector-perl_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('80aa49aea8c31c60c14161198eab9d620d738530c3c209104b8ad8f1144822f80c3effb3303c569fc556b2457328659ae5d1aaf511d714c835618b84c722abc5'
            '026e1dac01e3476c824a5aa55e5ae26c7dfc81677730a663636b4a5e863fb0893f0497b1f4d0098d646eeb3cd553d7a6b15d01e9893a0969c2817ed62ced2bce')

prepare() {
  cd Bit-Vector-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd Bit-Vector-$pkgver
  perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  cd Bit-Vector-$pkgver
  make DESTDIR="${pkgdir}" install
  install -Dm644 GNU_GPL.txt -t "${pkgdir}/usr/share/licenses/$pkgname"
}