# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=perl-berkeleydb
pkgver=0.64
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Interface to Berkeley DB version 2, 3 or 4"
arch=('i686' 'x86_64')
url="https://search.cpan.org/dist/BerkeleyDB/"
license=('GPL-1')
depends=('perl' 'db')
makedepends=('quilt')
options=('!emptydirs')
source=(https://search.cpan.org/CPAN/authors/id/P/PM/PMQS/BerkeleyDB-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/libb/libberkeleydb-perl/libberkeleydb-perl_$_debver-$_debrel.debian.tar.xz)
sha512sums=('368f89bb12e209ed6f0d1367875739813bfec85f4c10f0ffd7260d5be97bbd758af517133977f1e8f43c1d9b04d6b5dd9696ae1de1d544d9682b1f6bacfe3e85'
            '8b8f0a824a48f38052cae95b3deae2e44cd09a09c9ee086ad7a1b5b932e49cfc9c41ea2a66b75d942213f56f94e7c473bfc2ca7fb32db775b21d2ca528df4012')

prepare() {
  cd  "$srcdir"/BerkeleyDB-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd  "$srcdir"/BerkeleyDB-$pkgver
  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
  make
}

package() {
  _dbver1=`pacman -Q db | cut -d\  -f2 | cut -d- -f1 | cut -f1 -d.`
  _dbver2=`pacman -Q db | cut -d\  -f2 | cut -d- -f1 | cut -f2 -d.`
  depends=('perl' "db>=${_dbver1}.${_dbver2}" "db<${_dbver1}.$(expr $_dbver2 + 1)")

  cd  "$srcdir"/BerkeleyDB-$pkgver
  make pure_install doc_install DESTDIR="$pkgdir"
  find "$pkgdir" -name '.packlist' -delete
  find "$pkgdir" -name '*.pod' -delete

  install -Dm644 debian/copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}