# Maintainer: Jesus E. <heckyel@riseup.net>

# This package must not be "any" arch.
# The Build.PL script's '--with-sdl-config' acquires arch-specific library paths
# from the installed SDL instance, and puts that into the created package.
# Requires rebuild with every arch/config change in the provided SDL package.

pkgname=perl-alien-sdl
_realname=Alien-SDL
pkgver=1.446
_debver=$pkgver
_debrel=3.1
pkgrel=1
pkgdesc="Build, find and use SDL binaries"
arch=('i686' 'x86_64')
license=('GPL-1')
url='https://metacpan.org/dist/$_realname'
depends=('perl>=5.008' 'perl-capture-tiny'
         'perl-file-sharedir>=1.00' 'perl-file-temp' 'perl-pathtools'
         'sdl')
makedepends=('perl-archive-extract' 'perl-archive-tar' 'perl-archive-zip'
             'perl-digest-sha' 'perl-file-fetch>=0.24' 'perl-file-path>=2.08'
             'perl-file-which' 'perl-module-build>=0.36' 'perl-text-patch>=1.4'
             'quilt')
options=('!emptydirs')
source=("https://cpan.metacpan.org/authors/id/F/FR/FROGGS/${_realname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/liba/libalien-sdl-perl/libalien-sdl-perl_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('dfb5f104f449857b9567ca93a0c3b15aed2618e27019569c95c4b7469e1f7d5cc390fe2dda9c6add41e9648c1f6efe053d08a4bd0fcc5bc546a217721bea824c'
            '4d562c955aaf09c1e01bedd2de2d40c58854aa1fcce1f5f115f01782774a4a88d6d21b1b56f9ada64f3753c28512910983568dd3932ee4aa105e706f891c6ae3')

prepare() {
  cd "$_realname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  # Workaround bug with --with-sdl-config
  sed -i '/^GetOptions/d' Build.PL
}

build() {
  cd "$_realname-$pkgver"

  # install module in vendor directories
  perl Build.PL --with-sdl-config
  perl Build
}

package() {
  cd "$_realname-$pkgver"
  perl Build install installdirs=vendor destdir="$pkgdir"
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}