# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=pcc
pkgver=1.2.0
_debver=$pkgver
_debadd=20220331
_debrel=1
pkgrel=1
pkgdesc="A Portable C Compiler"
arch=('i686' 'x86_64')
license=('Modified-BSD' 'Simplified-BSD' 'GPL-3' 'ISC')
makedepends=('quilt')
options=('!strip' '!emptydirs')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/p/pcc/pcc_${pkgver}~DEVEL+${_debadd}.orig.tar.gz"
	"https://deb.debian.org/debian/pool/main/p/pcc/pcc_${_debver}~DEVEL+${_debadd}-${_debrel}.debian.tar.xz")
sha512sums=('ca18a7b2d29e55c6be071bc3bad7cd13b2f2a9352aa93407d1d2f146c6a1fe557a08ef3ce1de780e6e56d817c702fabec65228e12a2143111726eaef7c8dc5c6'
            'f7c5044d6aec7b17e0847d86de3b8772e836c2c2f0d8fa53effac3fee8f1ccaa80c7c85a7cecd6d475e6ad8a124e9b70b87766ca80a5faad57f2a67a36fc37bd')

prepare() {
  mv "${pkgname}-${_debadd}" "${pkgname}-${pkgver}"
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  export CFLAGS+=" -fcommon "
  ./configure \
    --prefix=/usr \
    --libdir=/usr/lib/ \
    --with-libdir=/usr/lib/ \
    --libexecdir=/usr/bin/ \
    --with-incdir=/usr/include/ \
    --enable-native=no \
    --disable-stripping
  make
}

package(){
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 debian/copyright -t "${pkgdir}/usr/share/licenses/${pkgname}"
}