# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=pangox-compat
pkgver=0.0.2
pkgrel=1
pkgdesc="X Window System font support for Pango"
arch=('i686' 'x86_64')
url='http://www.pango.org/'
license=('LGPL-2')
depends=('pango')
source=("https://gitlab.gnome.org/Archive/pangox-compat/-/archive/${pkgver}/pangox-compat-${pkgver}.tar.gz"
        "disable-shaper.patch")
sha512sums=('8e7ccec3a84fcc91400f5f42da3e39967bb9592078e69674cfc9d2686d03925be2b9a6f77a8a44395dc68b4b987ae0d27f12556f9e7d31b9bdffd4969a36ea42'
            'f8533aad00e912f4db4732d78ad93c79d460df75777a6ae1e907b177af4cb178e672a4968b333d68af053c50f2b1bbe5fae8c5387f7daccb2b2e6224e3121d46')

prepare() {
  cd ${pkgname}-${pkgver}
  patch -Nup1 -i '../disable-shaper.patch'
}

build() {
  cd ${pkgname}-${pkgver}

  if [ ! -s 'Makefile' ]; then
    NOCONFIGURE=1 ./autogen.sh
    ./configure \
      --prefix=/usr \
      --sysconfdir=/etc \
      --localstatedir=/var \
      --disable-static
    sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  fi
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make -j1 DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}