# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=pango
pkgver=1.46.2
_debver=1.46.2
_debrel=3
pkgrel=2
epoch=1
pkgdesc="A library for layout and rendering of text"
url="https://www.pango.org/"
arch=(i686 x86_64)
license=(LGPL-2)
depends=(libthai cairo libxft harfbuzz fribidi)
makedepends=(gobject-introspection help2man meson quilt)
source=(https://download.gnome.org/sources/${pkgname}/${pkgver:0:4}/${pkgname}-${pkgver}.tar.xz
        https://deb.debian.org/debian/pool/main/p/pango1.0/pango1.0_$_debver-$_debrel.debian.tar.xz)
sha512sums=('84308b217e5e0f80d7342b95fba0591788177b5954634aaaf92779a30d2f76dc757ba99607d951bf01478d2564a6480ecaa3f50853320d3a6b1f1145200d275e'
            'c72f642423a5d367a09df48572da691b740e252391d9b56623ff5677f5d35fe8d68cce8a07c45a270142a2af43049384d3677baf99141a6bf77080be8ca1a6d7')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  hyperbola-meson $pkgname-$pkgver build -D gtk_doc=false
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
  install -Dm644 $pkgname-$pkgver/COPYING $pkgdir/usr/share/licenses/$pkgname/COPYING
}