# Maintainer: Jesus E. <heckyel@riseup.net>

_pkgname=filter-rspamd
pkgname=opensmtpd-$_pkgname
pkgver=0.1.8
pkgrel=1
pkgdesc="OpenSMTPD filter integration for Rspamd"
arch=('i686' 'x86_64')
url='https://github.com/poolpOrg/filter-rspamd'
license=('ISC')
depends=('glibc')
makedepends=('gcc-go')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/poolpOrg/filter-rspamd/archive/refs/tags/v${pkgver}.tar.gz")
sha512sums=('54dc5ec496251e6a223ac05909f4d940c79ce2487e40e30a430da24fcc211983c40355fd91a609e7bb109be49051ca81f092e297f5c8c1e5a3e91a188b948f04')

export GOOS=linux
case "$CARCH" in
  x86_64) export GOARCH=amd64 ;;
  i686) export GOARCH=386 GO386=387 ;;
esac

build() {
  cd $_pkgname-$pkgver
  export CGO_CPPFLAGS="${CPPFLAGS}"
  export CGO_CFLAGS="${CFLAGS}"
  export CGO_CXXFLAGS="${CXXFLAGS}"
  export CGO_LDFLAGS="${LDFLAGS}"
  export GOFLAGS="-buildmode=pie -trimpath -ldflags \"-extldflags $LDFLAGS\""
  go build
}

package() {
  cd $_pkgname-$pkgver
  mv "$_pkgname-$pkgver" "$_pkgname"
  install -D filter-rspamd -t "$pkgdir"/usr/lib/smtpd/opensmtpd
  install -Dm644 README.md -t "$pkgdir"/usr/share/doc/${pkgname}
  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/${pkgname}
}