# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=openmotif
pkgver=2.3.8
_debver=2.3.8
_debrel=3
pkgrel=1
pkgdesc='Open Motif: GUI component toolkit'
arch=('i686' 'x86_64')
url='https://motif.ics.com/'
license=('LGPL-2.1')
depends=('libxp' 'libxft' 'libxmu' 'libpng' 'libjpeg')
makedepends=('xenocara-xbitmaps' 'xenocara-proto' 'quilt')
source=("https://downloads.sourceforge.net/project/motif/Motif%20$pkgver%20Source%20Code/motif-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/m/motif/motif_$_debver-$_debrel.debian.tar.xz")
sha512sums=('1ab8e8eece25ef97e948592b5fa3e19d98e932695290a18b7a8e90f1aa2766bc4f082bdbc3999dff5660e684821178a149040f76bb477163e53ca06474d02b55'
            'b8ae864d791d96ecd8b146c8e065090154a17c7e7b972fea38e60828811fe80ffc2e87f95679191db1d884e96a523730b8f3d1b26d6d1e72799c9130a9f3e480')

prepare() {
  cd motif-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  touch NEWS AUTHORS
  autoreconf -if
}

build() {
  cd motif-$pkgver
  ./configure --prefix=/usr
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd motif-$pkgver
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}