# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=oniguruma
pkgver=6.9.6
_debver=$pkgver
_debrel=1.1
pkgrel=2
pkgdesc="A regular expressions library"
arch=('i686' 'x86_64')
url='https://github.com/kkos/oniguruma'
license=('Simplified-BSD')
makedepends=('quilt')
source=("https://github.com/kkos/oniguruma/releases/download/v$pkgver/onig-${pkgver/_/-}.tar.gz"
        "https://deb.debian.org/debian/pool/main/libo/libonig/libonig_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('eb44f70347f49945fe054ad65370dbfd6b30b2e8442fb90b6c72413b7f9a8cb77ca98d1a4714d1d32b763551430436cc0175c0efaf2c73268363a9b6ecb5e3bc'
            'a42e3bc6cc9ae061817553b659a2acbbdd98a424240f2d685cbc9b3300083765b69c003cc2ca65f7edde830f512d4c09ffc45239ddc9b22a74caf2ec837a97cf')

prepare() {
  cd "$srcdir"/onig-${pkgver%_rev1}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir"/onig-${pkgver%_rev1}

  ./configure \
    --prefix=/usr \
    --enable-posix-api
  make
}

package() {
  cd "$srcdir"/onig-${pkgver%_rev1}

  make DESTDIR="$pkgdir" install
  install -dm755 "$pkgdir"/usr/share/doc
  cp -r doc "$pkgdir"/usr/share/doc/$pkgname
  for licfile in COPYING INSTALL; do
    install -Dm644 $licfile "$pkgdir"/usr/share/licenses/$pkgname/$licfile
  done
}