# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=ogmtools
pkgver=1.5
_debver=1.5
_debrel=4
pkgrel=1
pkgdesc="Information, extraction or creation for OGG media streams"
arch=('i686' 'x86_64')
url='https://www.bunkus.org/videotools/ogmtools'
license=('GPL-2')
depends=('libvorbis' 'libdvdread' 'gcc-libs')
makedepends=('quilt')
source=("https://www.bunkus.org/videotools/${pkgname}/${pkgname}-${pkgver}.tar.bz2"
        "https://deb.debian.org/debian/pool/main/o/ogmtools/ogmtools_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('1ed573531f9783c491a01e419667229b28540ad48c08b46131ae09ce3a4d771e3a54cde5dd09c585c0b85952e82abb3d1353864dc5223736f6eb6480158badee'
            '5e78395c1109db927fbe04b70e4b693ef907a78cd8eea4b80c0a31c047b8dd5b4142597b4d64e95b4d891a5603faa3636e36cc4c7a0b04a6e71ecd38e895b26d')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    rm -rf ./debian
    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure --prefix=/usr \
              --mandir=/usr/share/man
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}