# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=obmenu
pkgver=1.1.1
pkgrel=1
pkgdesc="Openbox menu editor"
arch=('any')
url='https://github.com/keithbowes/obmenu'
license=('GPL-2')
depends=('python' 'python-gobject' 'gtk')
makedepends=('gettext-tiny')
provides=('obmenu')
conflicts=('obmenu2')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/keithbowes/obmenu/archive/refs/tags/${pkgver}.tar.gz"
        "fix-build.patch")
sha512sums=('638f4cd40b9969bca958976b3935d9f92374cb4eae28300e8a989e21162a9966d26b83b093dc7bd1e47f28a8a160dafa0f1bba0853d504e7e11f983e096dc7ec'
            '7872502023ee732c8529689b8ff20c5e93f64e26a03858795165a0562ec63e1f7310110e00caaec6cc7277c8b5ed534f7b0662ebde142a72886ca5301422fec0')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -Np1 -i ${srcdir}/fix-build.patch
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make PREFIX="${pkgdir}/usr" install

  # fixing package-conflicts
  rm "${pkgdir}/usr/share/glib-2.0/schemas/gschemas.compiled"

  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}