# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=nift
_pkgname=nsm
pkgver=3.0.3
pkgrel=1
pkgdesc="Fast, free and libre cross-platform website generator"
arch=('i686' 'x86_64')
url='https://nift.dev'
license=('Expat')
depends=('gcc-libs' 'glibc')
source=("${_pkgname}-${pkgver}.tar.gz::https://github.com/nifty-site-manager/${_pkgname}/archive/v${pkgver}.tar.gz"
        "libre.patch")
sha512sums=('75aa7681b9c239852ebab0f9580d6adf7f220cf0478e473167b7ff174635deab2de3c471e207a5478f2def5b30dfd94524f440e9898ba0cc027d8ffbe4163bd1'
            '0300bf81e400822a46713c93af7e996b5b0d078c2dd04421a13c04b75857c90f92f72aa2823e29129b18f0838055eb96da0e65782266c1475362dc2ae628a5ac')

prepare() {
  cd "${_pkgname}-${pkgver}"
  patch -Np1 -i ${srcdir}/libre.patch
  sed -i 's|PREFIX?=/usr/local|PREFIX?=/usr|g; s|cp nsm nift|cp -l nsm nift|g' Makefile
}

build() {
  cd "${_pkgname}-${pkgver}"
  make -j1 all
}

package() {
  cd "${_pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}/" install
  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
}