# Maintainer: Jesus E. <heckyel@riseup.net>

_pkgname=neverball-libre
pkgname=neverball
pkgver=1.6.0
_debver=$pkgver
_debrel=3
pkgrel=3
pkgdesc="Free and libre 3D floor-tilting game"
arch=('i686' 'x86_64')
url='https://neverball.org/'
license=('GPL-3')
depends=('sdl2_ttf' 'libgl' 'libpng' 'libjpeg' 'libvorbis' 'physfs' 'hicolor-icon-theme' 'xdg-utils')
makedepends=('mesa' 'quilt')
groups=('games')
mksource=("https://neverball.org/${pkgname}-${pkgver}.tar.gz")
source=("https://repo.hyperbola.info:50000/sources/${_pkgname}/${_pkgname}-${pkgver}.tar.gz"{,.sig}
        "https://deb.debian.org/debian/pool/main/n/neverball/neverball_${_debver}+git20180603-${_debrel}.debian.tar.xz")
mksha512sums=('174d05308aee3a5e693782c54dd389439752b3597f28193771041d30f6c4236a5d055b2fcca9460b1005e9f000ddb3cbc01b86ea15c2abbf6e5a7996e836f787')
sha512sums=('5ceb145ac54ed8cbce93bafa05a3fcc39068fdd54bac6d0942505d24441f31ccae697dc509f473b082a2d0543d39ffae25277a9e207491a2eb17b3499b4720b4'
            'SKIP'
            'c0da341e66c78f01b57449993a675c2050757cbca6f91a9bf58b323954b6ebb807f4508ff4753eb66939569c4037ee47e8e502f5a74104d980b0f5bce46906e2')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

mksource() {
  cd ${pkgname}-${pkgver}

  # remove non-free data
  rm -rf data/ball/{blinky,octocat,rift}
}

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}

  make DATADIR=/usr/share/games/neverball LOCALEDIR=/usr/share/locale \
    CPPFLAGS="$CPPFLAGS -DNDEBUG" CFLAGS="$CFLAGS"
}

package(){
  cd ${pkgname}-${pkgver}

  install -d "${pkgdir}/usr/games"
  install -d "${pkgdir}"/usr/share/{games/neverball,locale,applications,doc/neverball}
  install -d "${pkgdir}"/usr/share/man/man{1,6}

  install -m755 neverball neverputt mapc "${pkgdir}/usr/games"
  cp -r locale/* "${pkgdir}/usr/share/locale/"
  cp -r data/* "${pkgdir}/usr/share/games/neverball/"
  cp -r doc/* "${pkgdir}/usr/share/doc/neverball/"
  install -m644 dist/*.desktop "${pkgdir}/usr/share/applications/"
  install -m644 dist/mapc.1 "${pkgdir}/usr/share/man/man1"
  install -m644 dist/{neverball.6,neverputt.6} "${pkgdir}/usr/share/man/man6"

  for i in 16 24 32 48 64 128 256 512; do
    install -D -m644 dist/neverball_$i.png "${pkgdir}/usr/share/icons/hicolor/${i}x$i/apps/neverball.png"
    install -D -m644 dist/neverputt_$i.png "${pkgdir}/usr/share/icons/hicolor/${i}x$i/apps/neverputt.png"
  done

  chmod -R u=rwX,go=rX "${pkgdir}/usr/share/games/neverball"

  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/doc/legal/license-GPL-3.0.txt" -t "${pkgdir}/usr/share/licenses/$pkgname"
}