# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=nethogs
pkgver=0.8.5
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="A net top tool which displays traffic used per process instead of per IP or interface"
url='https://github.com/raboof/nethogs'
license=('GPL-2')
arch=('i686' 'x86_64')
depends=('libpcap' 'ncurses' 'gcc-libs')
makedepends=('quilt')
source=("$pkgname-$pkgver.tgz::https://github.com/raboof/nethogs/archive/v$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/n/nethogs/nethogs_$_debver-$_debrel.debian.tar.xz")
sha512sums=('a2be81fcebc9925dd8a0fd9f71c6e790206819e0cc5efeeeb0c741baa9fd25ec685a1784b6d331d938cf14381403f9c13d619509d0ffe713ce8786a83a380908'
            '50bb385331f79c39f3c86705f3e9d5fcdcd0060ff3334eff3fea73af2f1a0020092c620bdbb185534bbb573685bb6b98d7886968b453302ab9ecaa87eb16de37')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  if [[ $CARCH = "i686" ]]; then
    export CXXFLAGS="-Og"
    export CFLAGS="-Og"
  fi

  make prefix="/usr"
  make prefix="/usr" libnethogs
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make prefix="/usr" DESTDIR="$pkgdir" install
  make prefix="/usr" DESTDIR="$pkgdir" install_lib

  install -Dm755 src/libnethogs.h "$pkgdir/usr/include/libnethogs.h"
  ln -s "/usr/lib/libnethogs.so.$pkgver" "$pkgdir/usr/lib/libnethogs.so"
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}