# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=nasm
pkgver=2.15.05
_debver=$pkgver
_debrel=1
pkgrel=3
pkgdesc='80x86 assembler designed for portability and modularity'
url='https://www.nasm.us'
arch=('i686' 'x86_64')
license=('Simplified-BSD')
depends=('glibc')
makedepends=('perl-font-ttf' 'perl-sort-versions' 'fontconfig' 'ttf-liberation' 'ghostscript' 'xmlto' 'asciidoc' 'quilt')
source=(https://www.nasm.us/pub/nasm/releasebuilds/${pkgver}/${pkgname}-${pkgver}.tar.xz
        https://deb.debian.org/debian/pool/main/n/nasm/nasm_$_debver-$_debrel.debian.tar.xz)
sha512sums=('512f90a2584f1c5811429274b97c64a2cedf37b9fdeffb1bcd0ea64afd9ecc19a2d7877ca8f1e05393aa324153fc9f39ea51dacbf8d25a7d5a2d7728c925dba7'
            '79895abded2a366ce5e051b2a9e8538758380e300bb2c1a6c8d72dbfdd2924c23850cc9a08b73ca6955a2b05ebd919af1264eb59f8b41ecbabe53ac4914986a2')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr
  make
  make -C doc
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install install_rdf
  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/nasm
}