# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=naev
pkgver=0.8.2
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="2D action/rpg space game"
arch=('i686' 'x86_64')
url='https://github.com/naev/naev'
license=('GPL-3')
depends=('glu' 'openal' 'libvorbis' 'sdl2' 'sdl2_image' 'sdl2_mixer' 'mesa-libgl'
         'libxml2' 'freetype2' 'libpng' 'libzip' 'luajit' 'suitesparse')
makedepends=('freeglut' 'zip' 'meson' 'quilt')
groups=('games')
source=("$pkgname-$pkgver.tar.gz::https://github.com/naev/naev/archive/v${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/n/naev/naev_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('c37a514dbe7ed1bca21563d20a4bb05892a07ee437eeaddefe00b5abe7009c2671da3c587db19bc8f1407db4ff3518f0cf5b28cb095778ba61946dcf87f61e5e'
            '45ca8729d7931bc732852429d6f8b8a5356d8ffad0b5a7e33bd93a490412dc6f82dc92f4d2b91393ab1597736831e6c2338480490304ed8a17074277b51445f9')

prepare() {
  cd "$pkgname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$pkgname-$pkgver"

  meson setup -Dprefix=/usr -Dbindir=/usr/games -Dndata_path=/usr/share/games/naev/ndata build .
  cd build
  meson compile
}

package() {
  cd "$pkgname-$pkgver/build"

  DESTDIR="$pkgdir" meson install

  # correct folder-structure within package
  cp "$pkgdir/usr/share/$pkgname/"{$pkgname.png,$pkgname-confupdate.sh} "$pkgdir/usr/share/games/$pkgname/"
  rm -rf "$pkgdir/usr/share/$pkgname/"

  # license
  install -Dm644 "$srcdir/$pkgname-$pkgver/LICENSE" -t "${pkgdir}/usr/share/licenses/$pkgname"
}