# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=mutt
pkgver=2.0.5
_debver=$pkgver
_debrel=4.1
pkgrel=2
pkgdesc="Small but very powerful text-based mail client"
url='http://www.mutt.org/'
license=('GPL-2')
arch=('i686' 'x86_64')
depends=('gdbm' 'glibc' 'libgpg-error' 'libressl' 'libsasl' 'mime-types' 'krb5' 'sqlite' 'zlib')
makedepends=('docbook-xml' 'docbook-xsl' 'elinks' 'git-legacy' 'gpgme' 'libidn2' 'lynx' 'ncurses' 'libxslt' 'quilt')
optdepends=('perl: for smime_keys'
            'python: for experimental mutt_oath2.py'
            'smtp-forwarder: to send mail')
backup=('etc/Muttrc')
source=("https://deb.debian.org/debian/pool/main/m/mutt/mutt_${pkgver}.orig.tar.gz"{,.asc}
        "https://deb.debian.org/debian/pool/main/m/mutt/mutt_${_debver}-${_debrel}+deb11u3.debian.tar.xz")
sha512sums=('41849d700b88e1b28b51fb90be2a9f6b639e8b111dce914073b66327e4655b5d4ca04dc3aedf2d44a0aa1a80ac3c4fcca6058eae7fb4f71f6b506fbe00a2a740'
            'SKIP'
            'b964776220d12a5cbf56336543f36afa385ca43d276741b73a4cceef0cd3552bfceb5c2bbf8885070f04ab8be55754eb4d7538972d85989deb6dbeb403b5c1e2')
validpgpkeys=('8975A9B33AA37910385C5308ADEF768480316BDA') # Kevin J. McCarthy <kevin@8t8.us>

prepare() {
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/debian-specific/467432-write_bcc.patch || true
    rm -v debian/patches/debian-specific/566076-build_doc_adjustments.patch || true
    rm -v debian/patches/debian-specific/document_debian_defaults.patch || true
    rm -v debian/patches/debian-specific/use_usr_bin_editor.patch || true
    rm -v debian/patches/debian-specific/Muttrc.patch || true

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --enable-debug \
    --enable-gpgme \
    --enable-pop \
    --enable-imap \
    --enable-smtp \
    --enable-hcache \
    --enable-sidebar \
    --enable-autocrypt \
    --with-curses=/usr \
    --with-gss=/usr \
    --with-ssl=/usr \
    --with-sqlite3 \
    --with-sasl \
    --with-idn2
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -vDm 644 contrib/gpg.rc "${pkgdir}/etc/Muttrc.gpg.dist"

  # /etc/mime.types is provided by mailcap
  rm "${pkgdir}"/etc/mime.types{,.dist}

  install -vDm 644 GPL -t "${pkgdir}/usr/share/licenses/${pkgname}"
}