# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=mtools
pkgver=4.0.32
pkgrel=1
pkgdesc="A collection of utilities to access MS-DOS disks"
arch=('i686' 'x86_64')
url='https://www.gnu.org/software/mtools/'
license=('GPL-3')
depends=('sh' 'glibc')
makedepends=('libx11' 'texinfo')
optdepends=('libx11: required by floppyd'
            'libxau: required by floppyd')
backup=('etc/mtools.conf')
source=("https://ftp.gnu.org/gnu/mtools/${pkgname}-${pkgver}.tar.bz2")
sha512sums=('a66e7483c422abdaddbe9e6b2cd0ecc2f87b0bc4f40929ac2e4db8b8d88cfacf118b126cba3207307bff376d5572170a1ee5803618de0544f68d420ed06bcab9')

prepare() {
  cd "${pkgname}-${pkgver}"
  # comment entry in default config
  sed -e '/^SAMPLE FILE$/s:^:# :' -i mtools.conf
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --infodir=/usr/share/info \
    --sysconfdir=/etc
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -vDm 644 mtools.conf -t "${pkgdir}/etc/"
  install -vDm 644 {README,NEWS} -t "${pkgdir}/usr/share/doc/${pkgname}"
  install -vDm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}