# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=msmtp
pkgname=('msmtp' 'msmtp-mta')
pkgver=1.8.11
_debver=$pkgver
_debrel=2.1
pkgrel=2
pkgdesc="A mini smtp client"
arch=('i686' 'x86_64')
url='https://marlam.de/msmtp/'
license=('GPL-3')
makedepends=('gsasl' 'quilt')
source=("https://marlam.de/msmtp/releases/${pkgbase}-${pkgver}.tar.xz"{,.sig}
        "https://deb.debian.org/debian/pool/main/m/msmtp/msmtp_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('77595ca3d06781aa908677edae08bef92840e69dde5db8eedb555327b671d87cde441181fa17342f5b9492e76f0520a49bfa86dafce9d93844137ae7f96eac16'
            'SKIP'
            '789b3ba7431df96ed5012c03261efc96eabd23914731c74bdec732c16c5fe627f323be03eb723d877193f2f0f5431a7680abe480c9848764fc0dec9e85e0db1c')
validpgpkeys=('2F61B4828BBA779AECB3F32703A2A4AB1E32FD34') # Martin Lambers <marlam@marlam.de>

prepare() {
  cd $pkgbase-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgbase-$pkgver
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --with-libgsasl
  make
}

package_msmtp() {
  pkgdesc="A mini smtp client"
  depends=('gsasl')

  cd $pkgbase-$pkgver
  make DESTDIR="$pkgdir" install

  # Installing example configs and scripts to /usr/share/doc/msmtp
  # as they are not installed by default (Debian and Gentoo do it this way)
  install -d "$pkgdir"/usr/share/doc/msmtp
  cp -r scripts/{find_alias,msmtpqueue,msmtpq,set_sendmail} "$pkgdir"/usr/share/doc/msmtp/
  install -D -m644 doc/*.example "$pkgdir"/usr/share/doc/msmtp/

  install -D -m644 scripts/vim/msmtp.vim "$pkgdir"/usr/share/vim/vimfiles/syntax/msmtp.vim

  chmod 755 "$pkgdir"/usr/share/doc/msmtp/{find_alias,msmtpqueue,set_sendmail}/*.sh
  chmod 755 "$pkgdir"/usr/share/doc/msmtp/msmtpq/msmtp*

  install -D -m644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
}

package_msmtp-mta() {
  pkgdesc="A mini smtp client - the regular MTA"
  depends=('msmtp')
  provides=('smtp-forwarder')
  conflicts=('smtp-forwarder')

  install -d "$pkgdir"/usr/bin
  ln -s msmtp "$pkgdir"/usr/bin/sendmail

  install -D -m644 "$pkgbase-$pkgver/COPYING" -t "$pkgdir"/usr/share/licenses/$pkgname
}