# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=msgpack-c
pkgver=3.3.0
_debver=3.3.0
_debrel=4
pkgrel=1
pkgdesc='An efficient object serialization library'
arch=('i686' 'x86_64')
url='https://msgpack.org/'
license=('Boost-1.0')
depends=('glibc')
makedepends=('cmake' 'quilt')
source=("https://github.com/msgpack/msgpack-c/releases/download/cpp-${pkgver}/msgpack-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/m/msgpack-c/msgpack-c_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('ad3e32edc8c6afd70282b3d4b493c2ffe74a697c41bd1f39030c5b4752cccefaa965bc049d4c2e63103a210bf714dc3bddd474691bc067d1475ae017593f55e6'
            '6fddd15b681a5f10d3013122e5dc3b8f33bf6756cc77fa9a9d10e66a3d47136acb38158daf6d4d4e06cb7f4054109c2b2c3f2e89a4a237c577e17433120e5862')

prepare() {
  cd "msgpack-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "msgpack-${pkgver}"
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_BUILD_TYPE=None \
        -DBUILD_SHARED_LIBS=ON \
        -DMSGPACK_ENABLE_STATIC=OFF \
        -DMSGPACK_CXX11=ON \
        -DMSGPACK_BUILD_EXAMPLES=OFF \
        .
  make
}

package() {
  cd "msgpack-${pkgver}"
  make DESTDIR="$pkgdir" install
  install -Dm644 LICENSE_1_0.txt -t "${pkgdir}/usr/share/licenses/$pkgname"
}