# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=mscgen
pkgver=0.20
_debver=0.20
_debrel=14
pkgrel=1
pkgdesc='Message Sequence Chart Generator'
arch=('i686' 'x86_64')
url='http://www.mcternan.me.uk/mscgen/'
license=('GPL-2')
depends=('gd')
makedepends=('quilt')
source=("https://www.mcternan.me.uk/mscgen/software/$pkgname-src-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/m/mscgen/mscgen_$_debver-$_debrel.debian.tar.xz")
sha512sums=('12fdea38633a42d6d235520550b16bea0cd3fb67d198b1f956845f4057239d7f80fa961e37f6f8bad9fb03f29ff8c6ffab4f4ae7402eea3083dfddeaf39687e3'
            'ff401339039a384be38fe1897300bdd6641b9963ff8c2094e8871ae64b2ff5841f177bb0e74b2248716853b107e7ba2ecac465efb33d021d12c8b9df5d67381e')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr --with-freetype
  make all
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}