# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=mp3gain
pkgver=1.6.2
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="Free and libre, lossless mp3 normalizer with statistical analysis"
arch=('i686' 'x86_64')
url='https://sourceforge.net/projects/mp3gain/'
license=('LGPL-2.1')
depends=('mpg123')
makedepends=('quilt')
source=("https://deb.debian.org/debian/pool/main/m/mp3gain/${pkgname}_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/m/mp3gain/${pkgname}_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('2afec934d6edb97528c30313231833c5e9d397ee47e81abe8ba068439d883d3ef052a6cfffd7ed6cc212acf4be3463f486212709a15c41b389c05a415d4cd9c3'
            'db45e1c6b48a7ba3132ad3f669a9ba6b24e1bd189c4823b4a3a1cff1f00483cada7fcfbde150a7afd1d6bbf3e2dfa6f2a0d43012076214cf573bddc88e1fa6e4')
noextract=("${pkgname}_${pkgver}.orig.tar.gz")

prepare() {
  mkdir -p "${pkgname}-${pkgver}"
  tar -xzf "${pkgname}_${pkgver}.orig.tar.gz" \
      -C   "${srcdir}/${pkgname}-${pkgver}/"

  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  make OSTYPE=linux
}

package() {
  cd $pkgname-$pkgver
  install -d "$pkgdir"/usr/bin
  make OSTYPE=linux INSTALL_PATH="$pkgdir"/usr/bin install
  install -Dm644 lgpl.txt -t "${pkgdir}/usr/share/licenses/$pkgname"
}