# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=moc
pkgver=2.6.0
_debver=$pkgver
_debrel=3
pkgrel=1
pkgdesc="An ncurses console audio player designed to be powerful and easy to use"
arch=('i686' 'x86_64')
url='https://moc.daper.net/'
license=('GPL-2')
depends=('libmad' 'libid3tag' 'jack' 'curl' 'libltdl' 'file' 'sndio' 'alsa-lib' 'jack' 'popt')
makedepends=('speex' 'ffmpeg' 'taglib' 'libmpcdec' 'wavpack' 'libmodplug' 'faad2' 'libsndio' 'quilt')
optdepends=('speex: for using the speex plugin'
	    'ffmpeg: for using the ffmpeg plugin'
	    'taglib: for using the musepack plugin'
	    'libmpcdec: for using the musepack plugin'
            'wavpack: for using the wavpack plugin'
            'faad2: for using the aac plugin'
	    'libmodplug: for using the modplug plugin')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/m/moc/moc_${pkgver}~svn-r3005.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/m/moc/moc_${_debver}~svn-r3005-${_debrel}.debian.tar.xz")
sha512sums=('97107410cad347e3ee747533aaad16300e906fbde033fa693a73a93e5042c4e7e42e35d0b914d1ed1a3e22576690d22abee66e0a82f703b224ba3402d1d020d2'
            'd2e01d7b3b65b0e3a4100dfcec3c8a810c4778ef90b767f096761394f98d4d4af922f7f7bafd109b23aed1f28912653678c7804ec42181ce0d6037c19b624ef9')

prepare() {
  mv "$pkgname-$pkgver~svn-r3005" "$pkgname-$pkgver"
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --without-rcc \
    --without-oss \
    --with-sndio \
    --with-alsa \
    --with-jack \
    --with-aac \
    --with-mp3 \
    --with-musepack \
    --with-vorbis \
    --with-flac \
    --with-wavpack \
    --with-sndfile \
    --with-modplug \
    --with-ffmpeg \
    --with-speex \
    --with-samplerate \
    --with-curl \
    --disable-cache \
    --disable-debug
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}