# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=mkvtoolnix
pkgname=('mkvtoolnix-cli' 'mkvtoolnix-gui')
pkgver=54.0.0
pkgrel=3
pkgdesc='Set of tools to create, edit and inspect Matroska files'
arch=('i686' 'x86_64')
url='https://mkvtoolnix.download/'
license=('GPL-2')
depends=('gcc-libs' 'glibc' 'pcre2' 'pugixml' 'boost-libs' 'libmatroska' 'libebml')
makedepends=('boost' 'cmark' 'docbook-xsl' 'flac' 'libdvdread'
             'libvorbis' 'qt-multimedia' 'qt-tools' 'zlib' 'ruby'
             'gettext-tiny' 'intltool')
source=("https://mkvtoolnix.download/sources/mkvtoolnix-${pkgver}.tar.xz")
sha512sums=('b055748fe3c417a1e1a95091080e5dddb3f6e8670157cbb0f8764297de04d785c2d8edcb42d14ec022593574e12baf0832915473d7502a39c0966fd6e5f15971')

prepare() {
  cd ${pkgbase}-${pkgver}
  ./autogen.sh
}

build() {
  cd ${pkgbase}-${pkgver}
  ./configure \
    --prefix=/usr \
    --disable-update-check
  rake $MAKEFLAGS
}

package_mkvtoolnix-cli() {
  depends+=('libdvdread' 'zlib' 'flac' 'libvorbis' 'libogg')

  cd ${pkgbase}-${pkgver}
  rake DESTDIR="${pkgdir}" install
  rm -rf "${pkgdir}"/usr/share/{applications,icons,metainfo,mime,mkvtoolnix}
  find "${pkgdir}" -name mkvtoolnix-gui* -delete
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}

package_mkvtoolnix-gui() {
  depends=('cmark' 'hicolor-icon-theme' 'mkvtoolnix-cli' 'qt-base' 'qt-multimedia')

  cd ${pkgbase}-${pkgver}
  rake DESTDIR="${pkgdir}" install
  rm -rf "${pkgdir}"/usr/share/locale
  for t in mkv{extract,info,merge,propedit}; do
    find "${pkgdir}" -name $t* -delete
  done
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}