# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=mjpegtools
pkgver=2.1.0
_debver=$pkgver
_debrel=6
pkgrel=5
pkgdesc="Set of tools that can do recording of videos and playback, simple cut-and-paste editing and the MPEG compression of audio and video"
arch=('i686' 'x86_64')
license=('GPL-2')
url="http://mjpeg.sourceforge.net/"
depends=('libjpeg-turbo' 'libpng' 'sdl' 'gcc-libs')
makedepends=('gtk2' 'v4l-utils' 'quilt')
optdepends=('gtk2: glav GUI')
options=('!makeflags')
source=(https://downloads.sourceforge.net/sourceforge/mjpeg/${pkgname}-${pkgver}.tar.gz
        https://deb.debian.org/debian/pool/main/m/mjpegtools/mjpegtools_${_debver}+debian-${_debrel}.debian.tar.xz)
sha512sums=('10d3288f47d7cc4de87fa63f65e0fd4bd0a9af95db77155eecccecae7a7e60ebab83eaec44cf7a2c3d9e627f0cc086eda208abee1a7a74cbf3f85e87bb979ac5'
            '5a5be6550548ba572fd984d0b48c81359cf17fca3a7aabd862fecb3bafc50305a24b733e505b147c631df361c324ca7d1eff75dde7c823b2b7b13c60550dd77e')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian/patches debian

    # Doesn't apply
    rm -v debian/patches/17_hurd.patch || true

    quilt push -av
  fi
  sed -i -e '/ARCHFLAGS=/s:=.*:=:' configure
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --enable-largefile
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -m644 mpeg2enc/mpeg2syntaxcodes.h "${pkgdir}/usr/include/mjpegtools/mpeg2enc/"
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}