# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=megaglest
pkgver=3.13.0
pkgrel=4
pkgdesc="A free and libre 3D real-time strategy game in a fantastic world"
arch=('i686' 'x86_64')
url='https://megaglest.org'
license=('GPL-3' 'CC-BY-SA-3.0')
provides=('megaglest' 'megaglest-data')
conflicts=('megaglest' 'megaglest-data')
depends=('curl' 'sdl2' 'libvorbis' 'openal' 'mesa-libgl'
         'lua' 'icu' 'ftgl' 'glew' 'libircclient' 'miniupnpc' 'wxgtk3'
         'glu' 'libx11' 'xz')
makedepends=('ftjam' 'cmake' 'mesa')
groups=('games')
source=("https://github.com/MegaGlest/megaglest-source/releases/download/${pkgver}/megaglest-source-${pkgver}.tar.xz"
        "https://github.com/MegaGlest/megaglest-data/releases/download/${pkgver}/megaglest-data-${pkgver}.tar.xz"
        "remove-xvfb-run.patch")
sha512sums=('5ae74efce55d7ec9f38d7701da9c865458e15223b5a3c5ac829e09dc81e63fbea2a235cae99450ea7333044c5166af82a762a29c5793c75711d1200688518b5c'
            'ac6a6dd85ec2e45d3107549199251b504f128b8fc254b683c7d9c0841b86cd4c32cd45c9d3cbddc3f989bd965d61ef5a0dca9212431876c00a13f8398ff45f4c'
            'c5dba27d9521c567ae14e1cc372f14154719ea54aaa13d6bab04d20242b9bde5502a63f87de1b8e8069da64c4174c7ce5f37d6562ac8dd36f65c22ad7737c2a8')
noextract=("megaglest-data-${pkgver}.tar.xz")

prepare() {
  mkdir -p megaglest-data-${pkgver}
  tar -xf  "megaglest-data-${pkgver}.tar.xz" --strip 1 \
      -C   "megaglest-data-${pkgver}"

  cd $srcdir/megaglest-${pkgver}

  # remove unneeded call
  patch -p1 -i ${srcdir}/remove-xvfb-run.patch
}

build() {
  cd $srcdir/megaglest-${pkgver}

  [[ -d build ]] && rm -r build
  mkdir build && cd build

  cmake .. \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_CXX_FLAGS="-lX11 ${CXXFLAGS}" \
    -DWANT_GIT_STAMP=0 \
    -DMEGAGLEST_BIN_INSTALL_PATH=games \
    -DMEGAGLEST_DATA_INSTALL_PATH=share/games/megaglest \
    -DwxWidgets_CONFIG_EXECUTABLE=/usr/bin/wx-config-gtk3 \
    -Wno-dev
  make

  cd $srcdir/megaglest-data-${pkgver}

  [[ -d build ]] && rm -r build
  mkdir build && cd build

  cmake .. \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DMEGAGLEST_BIN_INSTALL_PATH=games \
    -DMEGAGLEST_DATA_INSTALL_PATH=share/games/megaglest \
    -Wno-dev
}

package() {
  cd $srcdir/megaglest-${pkgver}/build

  make DESTDIR="${pkgdir}" install
  install -Dm644 "${srcdir}/megaglest-${pkgver}/docs/gnu_gpl_3.0.txt" -t "${pkgdir}"/usr/share/licenses/${pkgname}

  cd $srcdir/megaglest-data-${pkgver}/build

  make DESTDIR="${pkgdir}" install
  install -Dm644 "${srcdir}/megaglest-data-${pkgver}/docs/cc-by-sa-3.0-unported.txt" -t "${pkgdir}"/usr/share/licenses/${pkgname}
}