# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=mcabber
pkgver=1.1.2
_debver=1.1.2
_debrel=1
pkgrel=1
pkgdesc='A small Jabber console client, includes features: SSL, PGP, MUC, UTF8'
arch=('i686' 'x86_64')
url='https://www.lilotux.net/~mikael/mcabber/'
license=('GPL-2')
depends=('ncurses' 'glib2' 'loudmouth' 'gpgme' 'libotr' 'aspell')
makedepends=('pkg-config' 'quilt')
validpgpkeys=('EACADFF156849BC89653139E3C2900DEACB7FC95')
source=(https://www.lilotux.net/~mikael/mcabber/files/$pkgname-${pkgver/_/-}.tar.bz2{,.asc}
        https://deb.debian.org/debian/pool/main/m/mcabber/mcabber_${_debver}-${_debrel}.debian.tar.xz)
sha512sums=('bf53d593e84a4b4b2cf0230a4d94ea75f55008e3c2a839af5839519151209a61cce1685f9db14b65f5c4fa438bfabfeb25eb8e78e666b092c5c66af249788106'
            'SKIP'
            'b149dde679d8c5f2ad47da5b1a214839adb41704e38a98a236723694b2fc7f23d495cd12fa1ac466307c82e33121664799760ff5391254b23d89ef63aafb7340')

prepare() {
  cd "${srcdir}"/$pkgname-${pkgver/_/-}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}"/$pkgname-${pkgver/_/-}

  CFLAGS+=' -fcommon'
  ./configure --prefix=/usr --enable-hgcset \
      --mandir=/usr/share/man \
      --enable-aspell --enable-otr
  make
}

package() {
  cd "${srcdir}"/$pkgname-${pkgver/_/-}

  make DESTDIR="${pkgdir}" install
  mkdir -p "${pkgdir}"/usr/share/mcabber/example
  cp -a "${srcdir}"/$pkgname-${pkgver/_/-}/mcabberrc.example \
	"${pkgdir}"/usr/share/mcabber/example/mcabberrc
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}