# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=mc
pkgver=4.8.31
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="A file manager for the console"
arch=('i686' 'x86_64')
url='https://midnight-commander.org/'
license=('GPL-3')
depends=('e2fsprogs' 'glib2' 'gpm' 'libssh2' 'slang' 'which')
makedepends=('libxt' 'libx11' 'unzip' 'quilt')
optdepends=('aspell: spelling corrections'
            'cabextract: ucab extfs'
            'cdparanoia: audio extfs'
            'libisoburn: iso9660 extfs'
            'cvs: CVS support'
            'gawk: hp48+ extfs'
            'mtools: a+ extfs'
            'p7zip: support for 7zip archives'
            'perl: needed by several extfs scripts'
            'unar: urar extfs'
            'unzip: open zip archives'
            'zip: uzip extfs')
backup=('etc/mc/edit.indent.rc'
        'etc/mc/filehighlight.ini'
        'etc/mc/mc.ext'
        'etc/mc/mc.keymap'
        'etc/mc/mc.menu'
        'etc/mc/mcedit.menu'
        'etc/mc/sfs.ini')
options=('!emptydirs')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/m/mc/${pkgname}_${pkgver}.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/m/mc/mc_${_debver}-${_debrel}~bpo12+1.debian.tar.xz")
sha512sums=('dc2272a0016ed782eafc78efda575b04d064ffa7984a146f3389dea81f4c7886647e7d1f097b547f7ae00190c10e35979a24400a6bb936c023f190a82934c12d'
            '6b5defa3cd71234be6a258e96654a328bde749969955243336d4f963634ff5ca6bca85209a3159c7577d1a365f9e48393a2af0dd2542dd7453bb4adedbec6f0e')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/disable_internal_editor.patch || true
    rm -v debian/patches/ext_run-mailcap.patch || true
    rm -v debian/patches/ext_use_default_editor.patch || true
    rm -v debian/patches/use_sensible-editor.patch || true

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --libexecdir=/usr/lib \
    --sysconfdir=/etc \
    --with-screen=slang \
    --with-x
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install

  # Replace mc.keymap symlink with target file to fix backup mechanism
  rm "${pkgdir}"/etc/mc/mc.keymap && cp "${pkgdir}"/etc/mc/mc{.default,}.keymap

  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}