# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=lv2
pkgver=1.18.0
pkgrel=1
pkgdesc="Plugin standard for audio systems"
url="https://lv2plug.in/"
license=('ISC')
arch=('i686' 'x86_64')
makedepends=('asciidoc' 'doxygen' 'gtk2' 'libsndfile' 'pygmentize'
'python-markdown' 'python-pygments' 'python-rdflib' 'waf')
optdepends=('sord: for lv2_validate'
            'libsndfile: for eg-sampler.lv2'
            'atk: for eg-sampler.lv2 and eg-scope.lv2'
            'cairo: for eg-sampler.lv2 and eg-scope.lv2'
            'fontconfig: for eg-sampler.lv2 and eg-scope.lv2'
            'freetype2: for eg-sampler.lv2 and eg-scope.lv2'
            'glib2: for eg-sampler.lv2 and eg-scope.lv2'
            'gtk2: for eg-sampler.lv2 and eg-scope.lv2'
            'harfbuzz: for eg-sampler.lv2 and eg-scope.lv2'
            'pango: for eg-sampler.lv2 and eg-scope.lv2'
            'python-pygments: for lv2specgen.py'
            'python-rdflib: for lv2specgen.py')
source=("https://lv2plug.in/spec/${pkgname}-${pkgver}.tar.bz2"{,.sig})
sha512sums=('9e8dd9c1f30371260d21efc105b1d4d4ad03d9e332d4d3877d873f20b9527bcd0e917ff23fc6e0a9cc4337bda85882c742f225f7cf4fbc8a8a0964565c91f9d9'
            'SKIP')
validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3') # David Robillard <d@drobilla.net>

prepare() {
  cd "${pkgname}-${pkgver}"
  # let wscript(s) find the custom waf scripts
  mkdir -pv tools
  touch __init__.py
  cp -v waflib/extras/{autowaf,lv2}.py tools/
  mkdir -pv plugins/tools/
  cp -v waflib/extras/{autowaf,lv2}.py plugins/tools/
  rm -rv waflib
  sed -e 's/waflib.extras/tools/g' \
      -e "s/load('autowaf'/load('autowaf', tooldir='tools'/g" \
      -e "s/load('lv2'/load('lv2', tooldir='tools'/g" \
      -i {,plugins/,plugins/*/}wscript
}

build() {
  cd "${pkgname}-${pkgver}"
  waf configure --prefix=/usr \
                --libdir=/usr/lib \
                --docs \
                --test
  waf -v build $MAKEFLAGS
}

check() {
  cd "${pkgname}-${pkgver}"
  waf test
}

package() {
  cd "${pkgname}-${pkgver}"
  waf install --destdir="${pkgdir}"
  # license
  install -vDm 644 COPYING \
    -t "${pkgdir}/usr/share/licenses/${pkgname}/"
  # docs
  install -vDm 644 {NEWS,README.md} \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
}
# vim:set ts=2 sw=2 et: