# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=lugaru
pkgver=1.2
_debver=$pkgver
_debrel=5
pkgrel=1
pkgdesc="A third-person action game featuring a unique close-range combat system"
url='https://osslugaru.gitlab.io'
license=('GPL-2')
arch=('i686' 'x86_64')
depends=('sdl2' 'glu' 'libjpeg-turbo' 'libpng' 'openal' 'libvorbis' 'zlib')
makedepends=('cmake' 'quilt')
groups=('games')
source=("https://gitlab.com/osslugaru/lugaru/-/archive/${pkgver}/${pkgname}-${pkgver}.tar.bz2"
        "https://deb.debian.org/debian/pool/main/l/lugaru/lugaru_${_debver}-${_debrel}.debian.tar.xz"
        "$pkgname.png"
        "$pkgname.desktop")
sha512sums=('091f588523721617b973d72a26c0cfbeb75fe519707faefd00652cfd770b3be463b61b5c2be3721c644aac2337fa8f8455bc43a461b5a19b4c0e9741b517b9a4'
            'f4b84e7deb50524472e4aef887e4d984e763b2cb8b714408d65d74a5bcab15e989ddac23cb9b1784f4fc5ceb6510cddecb747236bc0ceff12d1ea16676539956'
            'd7dd014e9239473dfffc5c698d29fd515f0e026b75f37febbe9cf1373ea77d6928efe35252667663f43e1eaf0e529941f9d37ba72088fbd1ce76550bd77afdc8'
            '5df2da5ddd13d51626797d687ebb92ecc6f5981527342c7d21a8bae6458fcc7f7e360cf3492e18775e30d4f95c55d5be21363a4ba93d9fda3b02ab5482b14fcd')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cmake \
    -S ${pkgname}-${pkgver} \
    -B build \
    -DSYSTEM_INSTALL=ON \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_BINDIR=games \
    -DCMAKE_INSTALL_DATADIR=share/games \
    -DCMAKE_INSTALL_MANDIR=share/man
  make -C build
}

package() {
  make -C build DESTDIR="$pkgdir/" install
  rm -rf "$pkgdir/usr/share/icons"

  # install pixmap and desktop file
  install -Dm644 ${srcdir}/$pkgname.png "$pkgdir"/usr/share/pixmaps/$pkgname.png
  install -Dm644 ${srcdir}/$pkgname.desktop "$pkgdir"/usr/share/applications/$pkgname.desktop

  # install license
  install -Dm644 ${srcdir}/${pkgname}-${pkgver}/COPYING.txt -t "$pkgdir"/usr/share/licenses/$pkgname
}