# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=luajit
_pkgname=LuaJIT
pkgver=2.1.0.beta3
_pkgver=2.1.0-beta3
pkgrel=1
_debver=2.1.0~beta3+dfsg
__debver=2.1.0-beta3
_debrel=5.3
pkgdesc='Just-in-time compiler and drop-in replacement for Lua 5.1'
arch=(i686 x86_64)
url="https://$pkgname.org/"
license=(Expat)
depends=(gcc-libs)
makedepends=(quilt)
source=(https://$pkgname.org/download/$_pkgname-$_pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/l/$pkgname/${pkgname}_$_debver-$_debrel.debian.tar.xz)
sha512sums=('c44e967a0f671ed32b55aee810bc8b3b63737a2d7363b8984ae1949b24f98dbb3f9be7c1e10239fdeb96a3e3c836f606342cbd61838cf9bcadb077443eb5bc12'
            '0035b4ec06d75eda6699c56a5a4564504fe3d4d239432b7b4a60373de251f89099cff376d292ba3674d3bfe8faf5395bd152d2158d825d0167434e4024d464e6')

prepare() {
  cd $_pkgname-$_pkgver
  if [[ ${_pkgver%.*} = ${__debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $_pkgname-$_pkgver
  make amalg PREFIX=/usr
}

package() {
  cd $_pkgname-$_pkgver

  make install DESTDIR="$pkgdir" PREFIX=/usr

  ln -vs $pkgname-$_pkgver $pkgdir/usr/bin/$pkgname

  install -Dm644 COPYRIGHT "$pkgdir/usr/share/licenses/$pkgname/COPYRIGHT"
}

# vim:set sw=2 et: