# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=luasec
pkgname=('lua-sec' 'lua51-sec' 'lua52-sec')
epoch=1
pkgver=1.0
_debver=1.0
_debrel=1
pkgrel=1
pkgdesc='Lua bindings to provide TLS/SSL communication'
arch=('i686' 'x86_64')
url='https://github.com/brunoos/luasec/wiki'
license=('Expat')
makedepends=('lua51' 'lua51-socket' 'lua52' 'lua52-socket' 'lua' 'lua-socket' 'quilt')
depends=('libressl')
source=("https://deb.debian.org/debian/pool/main/l/lua-sec/lua-sec_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/l/lua-sec/lua-sec_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('70e81291b71111fb4976477d1c8ddbdaace17f017476b4e74b0ed88498e9e016d4ece1658f7fcce30f21aecab8dcf3734ce620940f61f2c70efb911c09a95bb9'
            '5691f5bd75320e77cc3d27f512c09bc69a71289c7227d21af87dac9d7c854cf556f78a2465cdfa1269f63bf43fe9032ae62c209687af873bd93d5c3f2893dacd')

prepare() {
  mv ${pkgbase}-${pkgver} ${pkgbase}
  cd ${pkgbase}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  cd ..
  cp -a ${pkgbase} ${pkgbase}-51
  cp -a ${pkgbase} ${pkgbase}-52
}

build() {
  cd "$srcdir"/${pkgbase}-51
  MYCFLAGS="$CFLAGS -fPIC" MYLDFLAGS="$LDFLAGS -shared" \
    make linux INC_PATH=-I/usr/include/lua5.1

  cd "$srcdir"/${pkgbase}-52
  MYCFLAGS="$CFLAGS -fPIC" MYLDFLAGS="$LDFLAGS -shared" \
    make linux INC_PATH=-I/usr/include/lua5.2

  cd "$srcdir"/${pkgbase}
  MYCFLAGS="$CFLAGS -fPIC" MYLDFLAGS="$LDFLAGS -shared" \
    make linux
}

package_lua51-sec() {
  pkgdesc="$pkgdesc for Lua 5.1"
  depends+=('lua51-socket')
  conflicts=('luasec')
  replaces=('luasec')

  cd ${pkgbase}-51
  make LUACPATH="$pkgdir/usr/lib/lua/5.1" LUAPATH="$pkgdir/usr/share/lua/5.1" install
  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_lua52-sec() {
  pkgdesc="$pkgdesc for Lua 5.2"
  depends+=('lua52-socket')

  cd ${pkgbase}-52
  make LUACPATH="$pkgdir/usr/lib/lua/5.2" LUAPATH="$pkgdir/usr/share/lua/5.2" install
  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

package_lua-sec() {
  pkgdesc="$pkgdesc for Lua 5.3"
  depends+=('lua-socket')

  cd ${pkgbase}
  make LUACPATH="$pkgdir/usr/lib/lua/5.3" LUAPATH="$pkgdir/usr/share/lua/5.3" install
  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}