# Maintainer: Jesus E. <heckyel@riseup.net>

pkgbase=lpeg
pkgname=(lua-lpeg lua51-lpeg lua52-lpeg)
pkgver=1.0.2
pkgrel=1
arch=('i686' 'x86_64')
url='http://www.inf.puc-rio.br/~roberto/lpeg'
license=('Expat')
makedepends=('lua' 'lua51' 'lua52')
source=("http://www.inf.puc-rio.br/~roberto/$pkgbase/$pkgbase-$pkgver.tar.gz"
        'LICENSE')
sha512sums=('110527ddf9f8e5e8a80ef0ae8847c8ba8cd2597dba3bfe2865cba9af60daafbb885f21e74231952f5ab793d021e050b482066a821c6954d52090a5eae77e9814'
            'f4c04e8a6bdbc737e04672f7751fcfb709e34c87df69ddfada0b0e22480f5ffd7daf21f266699e5b2955ff781f5a4aa574a614646896d12c994bc7b9282b0f67')

prepare() {
  sed 's/^CFLAGS =/CFLAGS +=/' -i $pkgbase-$pkgver/makefile
  sed 's/^COPT =/# COPT =/' -i $pkgbase-$pkgver/makefile

  cp -r $pkgbase-$pkgver $pkgbase-$pkgver-51
  cp -r $pkgbase-$pkgver $pkgbase-$pkgver-52
}

build() {
  cd $pkgbase-$pkgver
  make LUADIR=/usr/include

  cd "$srcdir"/$pkgbase-$pkgver-51
  make LUADIR=/usr/include/lua5.1

  cd "$srcdir"/$pkgbase-$pkgver-52
  make LUADIR=/usr/include/lua5.2
}

package_lua51-lpeg() {
  pkgdesc='Pattern-matching library for Lua 5.1'
  depends=('lua51')

  cd $pkgbase-$pkgver-51
  install -Dm755 $pkgbase.so "$pkgdir"/usr/lib/lua/5.1/$pkgbase.so
  install -Dm644 re.lua "$pkgdir"/usr/share/lua/5.1/re.lua
  install -Dm644 ../LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_lua52-lpeg() {
  pkgdesc='Pattern-matching library for Lua 5.2'
  depends=('lua52')

  cd $pkgbase-$pkgver-52
  install -Dm755 $pkgbase.so "$pkgdir"/usr/lib/lua/5.2/$pkgbase.so
  install -Dm644 re.lua "$pkgdir"/usr/share/lua/5.2/re.lua
  install -Dm644 ../LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}

package_lua-lpeg() {
  pkgdesc='Pattern-matching library for Lua 5.3'
  depends=('lua')

  cd $pkgbase-$pkgver
  install -Dm755 $pkgbase.so "$pkgdir"/usr/lib/lua/5.3/$pkgbase.so
  install -Dm644 re.lua "$pkgdir"/usr/share/lua/5.3/re.lua
  install -Dm644 ../LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
}