# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=lmarbles
pkgver=1.0.8
_debver=$pkgver
_debrel=0.2
pkgrel=3
pkgdesc="A game where you build figures out of colored marbles"
arch=('i686' 'x86_64')
url='https://lgames.sourceforge.net/index.php?project=LMarbles'
license=('GPL-2')
depends=('sdl_mixer')
makedepends=('quilt')
groups=('games')
source=("https://downloads.sourceforge.net/sourceforge/lgames/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/l/lmarbles/lmarbles_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('d765b669a1b0039a0af8b28ede8209e9736c2f967b21d9f8372d1fc5475d49a766bef297615bff090532ade41fe44e084a458227b443566a54afebc3e989b57a'
            '6a4a554460bc8a64a2b9b12449186b7ff7612ae240f640ab8d7abf9ba1ce0b332f5f8869bd8287a3e8e75034bea08c2ea764882af21836bc95c31210ddafb1aa')

prepare() {
  cd "${srcdir}"/$pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "${srcdir}"/$pkgname-$pkgver

  ./configure \
    --prefix=/usr \
    --localstatedir=/var \
    --bindir=/usr/games \
    --datarootdir=/usr/share/games
  make
}

package() {
  cd "${srcdir}"/$pkgname-$pkgver

  make DESTDIR="${pkgdir}" install
  mv "${pkgdir}"/usr/share/games/{applications,icons,man} "${pkgdir}"/usr/share
  rm "${pkgdir}"/usr/share/icons/*
  install -Dm644 debian/$pkgname.png -t "${pkgdir}"/usr/share/icons/
  install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/$pkgname
}