# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libxcb
_openbsdver=6.9
pkgver=1.14
pkgrel=2
pkgdesc="X11 client-side library, provided by Xenocara"
arch=('i686' 'x86_64')
url="https://www.xenocara.org"
depends=('xcb-proto>=1.14' 'libxdmcp' 'libxau')
makedepends=('libxslt' 'python' 'xenocara-util-macros')
license=('X11')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/dist/libxcb-$pkgver.tar.lz{,.sig}
        libxcb-1.14-no-missing-man-subdir.patch)
sha512sums=('a36234ce994690a0c41e9717bd222c16345548ba541bd4e64a782aabf9979967223af16a7103f80ae820b250141f11aa558f95f6f20a942aefcc244ee9646a22'
            'SKIP'
            'da2cb08143759db2097390429dceb5e0bdbc346b8106cb6c333661bd99b776a61ba48f50ec123bba4de606feca93b15aef2b7349dba43a996c8083708562126e')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/dist/libxcb"
  patch -Np1 -i "$srcdir/libxcb-1.14-no-missing-man-subdir.patch"
  chmod +x check-pc-requires
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/dist/libxcb"
  ./configure --prefix=/usr \
    --enable-xinput \
    --enable-xkb \
    --disable-static
  make -j1
}

check() {
  cd "xenocara-$_openbsdver/dist/libxcb"
  make -k check
}

package() {
  cd "xenocara-$_openbsdver/dist/libxcb"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}