# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libvorbis
pkgver=1.3.7
_debver=1.3.7
_debrel=1
pkgrel=1
pkgdesc='Vorbis codec library'
arch=('i686' 'x86_64')
url='https://www.xiph.org/vorbis/'
license=('BSD')
depends=('libogg')
makedepends=('quilt')
source=(https://downloads.xiph.org/releases/vorbis/$pkgname-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/libv/libvorbis/libvorbis_$_debver-$_debrel.debian.tar.xz)
sha512sums=('8a83ac9e9197f32fad4430946dba3927921320492f9e96cda546e8eb3981e2664da97f77e43cb197577ec056437785168ca7c4138f8bf7f2ba93899846932eb2'
            '2bd8195afb8df90dc76d8cebda9c5ec9aa06180e3bcc28f13714e098b31288f77670c9ed16f69697bb190791ea15a876cb165947da6e82e0c6105f665ee2fa8b')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver

  ./configure \
    --prefix='/usr' \
    --disable-static
  make
}

check() {
  cd $pkgname-$pkgver

  make -j1 check
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}