# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libtiff
pkgver=4.2.0
_debver=$pkgver
_debrel=1
pkgrel=3
pkgdesc="Library for manipulation of TIFF images"
url='http://www.simplesystems.org/libtiff/'
arch=('i686' 'x86_64')
license=('custom:Hylafax')
depends=('libjpeg-turbo' 'zlib' 'xz')
makedepends=('freeglut' 'glu' 'mesa' 'jbigkit' 'quilt')
optdepends=('freeglut: for using tiffgt')
source=("https://download.osgeo.org/libtiff/tiff-${pkgver}.tar.gz"{,.sig}
        "https://deb.debian.org/debian/pool/main/t/tiff/tiff_${_debver}-${_debrel}+deb11u4.debian.tar.xz")
sha512sums=('d7d42e6e6dbda9604c638f28e6cfa4705191a4e8ea276d18031d50dbab0931ac91141e57a2cf294124487f1a2e6dfcb9be62431c1b69de5acf4d0e632f3322e5'
            'SKIP'
            'a0a647e7daba4239210e8d9487c49a0ccc2af4c6072e91d2f74f18d985798e3694522199cc6ae4ccec629ff497d516d5a2fa9f0d9e8035dc322f563f8c9bfb4e')
validpgpkeys=('EBDFDB21B020EE8FD151A88DE301047DE1198975') # Bob Friesenhahn <bfriesen@simple.dallas.tx.us>

prepare() {
  cd tiff-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .
    quilt push -av
  fi
}

build() {
  cd tiff-${pkgver}
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --mandir=/usr/share/man \
    --disable-zstd \
    --with-docdir=/usr/share/doc/${pkgname}
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  make
}

package() {
  cd tiff-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm 644 COPYRIGHT -t "${pkgdir}/usr/share/licenses/${pkgname}"
}