# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=libtheora
pkgver=1.1.1
_debver=1.1.1+dfsg.1
_debrel=15
pkgrel=4
pkgdesc="A free video codec developed by the Xiph.org"
arch=('i686' 'x86_64')
url="https://www.theora.org/"
license=('Modified-BSD')
depends=('libogg')
makedepends=('libvorbis' 'quilt')
source=(https://downloads.xiph.org/releases/theora/libtheora-${pkgver}.tar.bz2
        https://deb.debian.org/debian/pool/main/libt/libtheora/libtheora_$_debver-$_debrel.debian.tar.xz
        libtheora-1.1.1-libpng16.patch)
sha512sums=('9ab9b3af1c35d16a7d6d84f61f59ef3180132e30c27bdd7c0fa2683e0d00e2c791accbc7fd2c90718cc947d8bd10ee4a5940fb55f90f1fd7b0ed30583a47dbbd'
            'ebee94506621c7220bb2febb63f5444a65d7c8b49d611058799dc51504f3152b49313542b0007b225d0fe94ed3d2a6fc0db51b344844e25a0496e547e1be1d40'
            '856da5da7788863c59c9cb6c4fa102d250e60d6b302a5c118799169bcbc5350ab0bf6798f2ae2586f1d361ff9030d1d715214d8df900d7e1aa4a4e1d58f44276')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  else
    patch -Np0 -i ../libtheora-1.1.1-libpng16.patch
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure --prefix=/usr --enable-shared --disable-static
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install

  install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -m644 LICENSE COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
}